@echo off
color 0b

echo 该批处理将帮助您控制Wamp下的Mysql5.1服务器。

rem 设置路径
set wamp_home=%~dp0
set mysql_bin=%wamp_home%mysql5.1\bin\

:select
echo =====请选择要进行的操作=====
echo [0]退出 [1]启动 [2]重启 [3]停止 [4]安装并启动 [5]停止并卸载
set /p type=:

if %type% == 0 goto exit
if %type% == 1 goto start
if %type% == 2 goto restart
if %type% == 3 goto stop
if %type% == 4 goto install
if %type% == 5 goto uninstall
if %type% == 6 goto initial

if %type% GTR 6 goto end
if %type% LSS 1 goto end

:start
echo 启动Mysql5.1...
net start | find /i "MySQL">NUL
if %errorlevel%==0 (
echo 服务已经启动，终止当前启动操作。
goto end)
net start MySQL
goto end

:restart
echo 重新启动MySQL...
net start | find /i "MySQL">NUL
if %errorlevel%==0 net stop MySQL
net start MySQL
goto end

:stop
echo 停止MySQL...
net start | find /i "MySQL">NUL
if %errorlevel%==0 (
net stop MySQL
)ELSE (
echo 未检测到服务在运行。)
goto end

:install
echo 安装MySQL作为服务...
%mysql_bin%mysqld --install MySQL --defaults-file="%wamp_home%mysql5.1\my.ini"
echo Mysql5.1.39在注册服务时存在bug(http://bugs.mysql.com/bug.php?id=46917)。现在Fix it...

rem 删除原 HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\MySQL 中ImagePath项
reg delete HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\MySQL /v ImagePath /f

rem 添加新的ImagePath项以修正bug
reg add HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\MySQL /v ImagePath /t REG_EXPAND_SZ /d "%wamp_home%mysql5.1\bin\mysqld --defaults-file=\"%wamp_home%mysql5.1\my.ini\" MySQL" /f

net start MySQL
goto end

:uninstall
echo 卸载MySQL服务...
net start | find /i "MySQL">NUL
if %errorlevel%==0 net stop MySQL
%mysql_bin%mysqld --remove

goto end

:initial
echo 初始化Mysql5.1配置文件，当第一次安装时需要使用.
echo 开始初始化...
echo 生成mysql5.1配置文件到 %wamp_home%mysql5.1\my.ini:
copy /-y %wamp_home%mysql5.1\ref\my-wamp.ini %wamp_home%mysql5.1\my.ini
echo ----------------
echo 生成默认mysql数据库mysql(root口令为空):
xcopy %wamp_home%mysql5.1\ref\default-table-mysql %wamp_home%mysql5.1\data\mysql\ /-y /q
echo 
echo 完成初始化。
goto end

:end
goto select

:exit
echo 脚本结束。
pause